各编程语言相互调用示例，代码简单，生成的软件体积也很小
cac55 2024-09-20 12:58 36 浏览 0 评论
aardio 支持混入很多不同的编程语言，代码简单，生成的软件体积也很小。下面看示例。
aardio 直接调用系统 API 函数( 支持回调、相互调用 )：
var ret,point = ::User32.GetCursorPos({
int x;
int y;
})
aardio / JavaScript 相互调用（ 支持 ES6 ）:
import web.script;
var vm = web.script("ES6")
//导出 aardio 函数到 JavaScript
vm.external = {
log = function(...){
console.log(...)
}
}
vm.script = /*****
function TestFunction(a,b) {
return a + b;
}
*****/
var ret = vm.script.TestFunction(2,3);
在 aardio 中调用 Python（ Python 调用 aardio 同样简单，参考 aardio 自带范例），简单得就像在 Python 中使用 Python：
import console;
import py3;
//导入 Python 模块。
var itertools = py3.import("itertools")
//调用 Python 函数，支持纯 aardio 类型参数
var permutations = itertools.permutations({"a","b","c"});
//调用 Python 内置函数 list
var pyList = py3.list(permutations);
//遍历 Python 对象成员
for( item in pyList.each() ){
console.log(item); //像 aardio 对象一样使用 Python 对象
}
console.pause();
aardio 直接调用 .Net / C# 组件（ 支持相互调用，支持委托这些）
import win.ui;
var winform = win.form(text="DataGridView")
import System.Data;
var tab = System.Data.DataTable("DT");
tab.Columns.Add("名称");
tab.Rows.Add({"WangWu"});
import System.Windows.Forms;
var grid = System.Windows.Forms.CreateEmbed("DataGridView",winform);
grid.ColumnHeadersHeightSizeMode = 2;
grid.DataSource = System.Data.DataView(tab);
winform.show();
win.loopMessage();
aardio 直接调用 Java （ 也支持相互调用 ）
import java;
var jvm = java();
//加载Java类对象
HelloworldApp = jvm.import("aardio.sample.HelloworldApp");
//也可以如下自内存或文件直接加载类,
HelloworldApp = jvm.import("aardio.sample.HelloworldApp",#34;\java\aardio\sample\HelloworldApp.class");
//用 Java 类创建 Java 对象
var helloworld = HelloworldApp();
//直接调用 Java 对象的方法
var result = helloworld.test(3);
用 aardio 编译 C 语言代码生成 DLL 执行文件，再调用 DLL 中的 C 函数：
import tcc;
//编译 DLL
tcc.build( "/start.dll" ).code = /***
#include <windows.h>
__declspec(dllexport) int Add( int a,int b )
{
return a + b;
}
***/
//加载 DLL
var dll = raw.loadDll( "/start.dll",,"cdecl" );
//调用 C函数
var result = dll.Add(12,3);
在 aardio 中嵌入并调用批处理：
import console
import process.batch;
//批处理 for 遍历并拆分字符串
var bat = process.batch(`
@echo off
for %%i in (abc,def,xyz) do echo %%i
`)
console.log(bat.read(-1))
console.pause()
aardio 调用 Rust 语言解析 TOML:
import console;
import string.toml;
var str = string.toml.stringify({abc=123,d={1,2,3}});
console.log( str );
import process.code;
process.code("~\lib\string\toml\.res");
console.pause(true);
在 aardio 里嵌入 PHP，以下短短几句代码，包含了 HTTP 服务器，PHP服务端，嵌入的浏览器组件:
import win.ui;
/*DSG{{*/
var winform = win.form(text="Hello World / PHP_CGI 服务器")
/*}}*/
var code = /*
<html>
<head>
<meta charset="utf-8">
<title>PHP 测试</title>
</head>
<body>
<?php echo '<p>Hello World / PHP_CGI 服务器</p>'; ?>
</body>
</html>
*/
string.save("/test.php",code);
import php.simpleHttpServer;
var url = php.simpleHttpServer.startUrl("/test.php");
import web.form;
var wb = web.form(winform);
wb.go(url);
winform.show();
win.loopMessage();
aardio 调用 PowerShell，并且在 PowerShell 中调用 aardio。这甚至都不用带上体积较大的 System.Management.Automation.dll，一个轻巧的 EXE 就可以搞定一切，向下兼容到 PowerShell 2.0 ：
import dotNet.ps;
var pScript = /*
# 声明 PowerShell 参数
param($win)
# 修改 aardio 对象属性
$win.title = "PowerShell + aardio";
# 调用 aardio 对象函数
$win.msgbox("这是 PowerShell 调用 aardio 打开的对话框。")
*/
import win;
dotNet.ps(pScript,{
win = win; //# 将 aardio 对象作为参数传给 PowerShell
});
aardio 执行 Ruby 语言代码 ：
import win.ui;
/*DSG{{*/
var winform = win.form(text="执行Ruby代码")
winform.add(
edit={cls="edit";left=26;top=16;right=737;bottom=435;multiline=1;z=1}
)
/*}}*/
import process.ruby;
var out = process.ruby.exec("puts '测试UTF-8'")
winform.edit.print(out);
var out = process.ruby.eval(`[1, 2, { name: "tanaka", age: 19 }]`)
winform.edit.print(out);
winform.show();
win.loopMessage();
aardio 调用 Node.js ：
import console;
import nodeJs;
var js = /******
console.log(process.argv);
var startEnviron = require('startEnviron');
console.log(startEnviron.dest);
******/
//自动分析 JS 代码中的 require 语句并安装依赖模块
nodeJs.requireByJs(js);
//把对象传给 node.js，在 JS 代码中用 require('startEnviron') 获取。
nodeJs.startEnviron({
src:"传个字符串",dest:{test:"嵌套的对象表，传给node.js都没问题",number:123, arr:{1,2,3} }
})
//执行JS，这里指定的启动参数在 JS 代码中可用 process.argv 获取。
var prcs = nodeJs.exec(js,"--args1=1","--args2=1");
prcs.logResponse();
console.pause(true);
aardio 调用 Fortran ( DLL 源码在 aardio 范例里有 ) ：
import console
//加载 DLL , DLL 路径前加 $ 实现内存加载 DLL(发布后不需要外部 DLL 文件)
var dll = raw.loadDll(#34;/fortran.dll",,"cdecl");
//不声明直接调用，结构体默认传址，这不用改什么。
var c = dll.__test_MOD_addbypoint({
int x = 22;
int y = 3;
})
console.log(c);
//可以先声明一下，参数类型加上&声明为按引用传址（指针）
var add = dll.api("__test_MOD_add","int(int &a,int &b)")
var c = add(33,2); //Fortran 的数值参数默认都是传址（传指针）
//不声明直接调用可以用结构体取代指针
var c = dll.__test_MOD_add({int a=33},{int b=2});
//用 raw.int 创建传址数值也可以
var c = dll.__test_MOD_add(raw.int(33,true),raw.int(2,true));
//参数声明为传值时调用更简单，不声明调用时数值默认为 int 类型
var c = dll.__test_MOD_addbyval(33,2,raw.double(123));
console.log(c);
//字符串
var str = "hello"; //只读字符串，改用 raw.buffer 创建可读写字节数组
dll.__test_MOD_hello(str,#str); //注意到字符串长度传过去
console.pause(true);
aardio 调用 C++ ：
import vc6;
import console;
console.open();
var vc = vc6( "/" )
//输入C++源码
vc.cpp = /******
#include <windows.h>
struct TestInfo{
int x;
int y;
BYTE name[256];
};
class CTestObject
{
public:
//注意函数声明前加上 virtual 以支持 aardio 中的 raw.interface
virtual void getName(char *buffer,int len);
virtual void getInfo(TestInfo *pInfo);
};
void CTestObject::getName(char *buffer,int len){
strcpy(buffer,"测试");
}
void CTestObject::getInfo(TestInfo *pInfo){
pInfo->x = 1;
pInfo->y = 2;
strcpy((char *)pInfo->name,"测试");
}
extern "C" __declspec(dllexport) CTestObject* __cdecl CreateTestObject() {
return new CTestObject();
}
extern "C" __declspec(dllexport) void __cdecl DeleteTestObject( CTestObject* pTest) {
delete pTest;
}
******/
//编译生成DLL
vc.exec(
'cl *.cpp'
,'/W3' /*警告等级*/
,'/MD' /*使用多线程动态运行库*/
,'/O2 /Ot /EHsc' /*代码优化选项*/
,'/D "WIN32" /D "_WINDOWS" /D "_MBCS" /D "_USRDLL"' /*定义常数和宏*/
,'/I"./INCLUDE"'/*指定头文件目录*/
,'kernel32.lib user32.lib gdi32.lib winspool.lib comdlg32.lib advapi32.lib shell32.lib ole32.lib oleaut32.lib uuid.lib odbc32.lib odbccp32.lib' /*导入库*/
,'/link /SUBSYSTEM:WINDOWS /MACHINE:X86' /*后面是链接参数 */
,'/out:test.dll'/*输出文件名*/
,'/dll' /*输出DLL*/
,'/LIBPATH:".\LIB" /LIBPATH:".\LIB2"' /*指定库目录*/
)
var dll = raw.loadDll("/test.dll",,"cdecl");
import raw.interface;
class testObject{
ctor(){
//创建 C++ 对象,并获取指针，注意这里使用了 P 尾标获取指针。
var pTest = dll.CreateTestObjectP();
//C++ 对象指针转换为 aardio 对象。
this = ..raw.interface( pTest,"
void getName(string &buffer,int len);
void getInfo(struct &pInfo);
","thiscall" //注意调用约定为thiscall
)
//添加析构函数
..table.gc(this,"delete")
};
delete = function(){
if(!owner.deleted){
dll.DeleteTestObject( owner );
owner.deleted = true;
}
};
}
//创建对象
var obj = testObject();
//调用 C++ 函数
var name = obj.getName(25,25);
console.log(name);
//调用 C++ 函数
var info = obj.getInfo({ int x;int y;BYTE name[256]})
console.log( info.name );
console.pause();
aardio 调用 FreeBASIC ( DLL 源码在 aardio 范例里有 ） ：
//加载DLL,DLL路径前面加上$表示把DLL嵌入到程序中并通过内存加载
var dll = raw.loadDll(
#34;\basic.dll",,"cdecl" //注意参数里指定使用 cdecl 调用约定。
);
//定义结构体，当然也可以先声明一个 class 来创建实例。
var info = {
int x;
INT y;
}
// 然后直接调用 API
var ret = dll.msgboxW(123,456,"测试一下好用不好用",info);
//最后打印结构体看一下值
import console;
console.log(ret);
console.dumpJson(info);
console.pause();
aardio 调用 Delphi （ DLL 源码在 aardio 范例里有） ：
import win.ui;
//内存加载 DLL
var delphiDll = raw.loadDll(#34;\Project1.dll");
class win.ui.ctrl.delphiForm{
ctor(parent,tParam){
this.hwnd = delphiDll.CreateForm(parent.hwnd);
};
@..win.ui.ctrl.metaProperty()
}
/*DSG{{*/
var winform = win.form(text="用 Delphi 语言为 aardio 编写控件";right=507;bottom=423;bgcolor=11842740)
winform.add(
custom={cls="delphiForm";text="嵌入 Delphi 控件";left=17;top=28;right=490;bottom=211;db=1;dl=1;dr=1;dt=1;z=1};
edit={cls="edit";text="请先用 Delphi 打开此目录下的 DLL 源码工程编译生成 \Project1.dll";left=16;top=228;right=489;bottom=398;edge=1;multiline=1;z=2}
)
/*}}*/
import web.json;
winform.onTest = function(delphiStructParam){
winform.edit.print("Delphi 调用了aardio 函数,参数如下:");
winform.edit.print(delphiStructParam);
delphiStructParam.x = 90;
//可选返回修改后的结构体
return delphiStructParam;
}
winform.edit.text = "";
winform.show();
win.loopMessage();
aardio 调用 R 语言：
import console;
import process.r;
//执行 R 代码，支持 aardio 模板语法
process.r.code = /*
write("<?="这是 aardio 代码"?>",file=".data.txt");
*/
//执行 R 代码，支持 aardio 模板语法
var out = process.r.loadcode(`write("<?="这是 aardio 代码"?>",file=".data.txt");`)
//执行纯 R 代码，参数 @1 可以指定 R代码或 R 文件。
var out = process.r.exec(`
args=commandArgs(T);
write(args[1],file=".data.txt");
# list 有点像 aardio 中的表(table)，可以包含各种数据类型，
a <- list(hello = 1, world = "字符串" ) # <- 相当于 aardio 中的等号, R的等号一般用于分隔键值对
print ( a[["world"]] ); # aardio 里的直接下标也是这么写
print ( a$world ); # 相当于 aardio 里的 a.world
print ( a[1] ); # 这个返回的是键值对 hello = 1，不像 aadio 中 a[1] 与 a.hello 是指向不同的元素。
print ( mode(a[1]) ); # 数据类型还是显示为 list
b <- TRUE #布尔值必须全大写
print( b )
# 向量
a = c(10, 20, 30, 40, 50)
print( a[1] ) #起始下标为 1 ,这跟 aardio 一样
print( a[1:4] ) # 取出第 1 项到第 4 项
# 定义函数，与 aardio 语法类似
new.function <- function(a,b,c) {
result <- a * b + c # 类似 aardio 中的 return a * b + c #
print(result) # 指定返回值以后，还能继续执行后面的代码，不像 aardio 函数 return 后面的代码被忽略。
}
print( new.function(2,3,1) )
`,"测试一下"); //可以添加不定个数的启动参数
console.log( out );
console.more(,true);
console.showLoading(" 正在安装 rjson 包");
process.r.require("rjson","https://mirrors.ustc.edu.cn/CRAN/");//不会重复安装
var out = process.r.exec( `
library("rjson") # 载入 rjson 包
args <- commandArgs(T);
tab <- fromJSON(args[1], simplify=FALSE);
#不要用 print ，cat 不会加一堆不必要的东西
cat( toJSON(tab) )
`, {
name1 = "测试一下，传对象给 R 语言";
name2 = "这是一个 aardio 对象"
})
console.dump(out);
var rCode = /*
testabc <- function(a,b,c) {
result <- a * b + c # 类似 aardio 中的 return a * b + c #
print(result) # 指定返回值以后，还能继续执行后面的代码，不像 aardio 函数 return 后面的代码被忽略。
}
*/
//启动 R
var r = process.r.startRpc(rCode);
//调用 R 函数
var ret = r.testabc(2,3,1)
//打印 R 函数返回值
if(ret[["result"]]){
console.log("R 函数返回值",ret[["result"]])
}
console.pause(true);
aardio 调用 Julia :
import console;
import julia;
//调用 Julia 函数
var ret = julia.sqrt(2);
console.log(ret);
//导入 Julia 模块
julia.using("Base64");
var data = julia.Base64.base64encode("测试一下");
console.log( data );
//转换 Julia 数据类型
var buf = julia.value.build(raw.buffer("abc"));
console.log(julia.typeof(buf));
//执行 Julia 代码并获取返回值
var refs = julia.eval("refs = IdDict(");
//查看 Julia 代码错误
console.log(julia.lasterr());
console.pause();
aardio 调用 Nim 语言：
import console;
var nimCode = /*
{.pragma: rtl, exportc, dynlib, cdecl.}
import md5
# Nim 双引号中的字符串，相当于 aardio 中用单引号包含的转义字符串
# aardio 中双引号包含的字符串，相当于 Nim 中的原始字符串： r"原始字符串"
# Nim 与 aardio 都是 UTF-8 编码，aardio 的文本字符串在 Nim 中的类型为 cstring
# Nim 中 string 可以隐式转换为 cstring, cstring 加上 $ 转为 string 类型
proc build*(str: cstring, num: ptr[cint]): cstring {.rtl.} =
num[] = num[] * 2
result = md5.getMD5($str)
*/
string.save("/test.nim",nimCode )
import process.nim;
process.nim("c --app:lib -d:release -r test.nim")
//支持改为 #34;/test.dll" 内存加载 DLL,
//但这时候 test.dll 还未生成，所以示例里没有加 $
//用cdecl 调用约定的好处是：导出函数名直接可用，不会被加上修饰名
var test = raw.loadDll("/test.dll",,"cdecl")
//nim 与 aardio 的字符串都是 UTF-8 编码，UTF-8 真是到处通行，非常方便省了很多事
var build = test.api("build","str(str,int& num)" )
//一般C语言不能这么直接返回字符串(要考虑谁释放内存)。
//但是 nim 可以投机取巧一下，nim 会自动回收内存，而这时候还来不及回收。
var str,num = build("测试abc",9)
console.log(str,num)
//用 aardio 算出 MD5 对比一下，结果一模一样
import crypt;
console.log(crypt.md5("测试abc",false))
console.pause();
aardio 调用 V 语言：
import console;
import process.v;
console.open();
//V语言不支持中文路径，所以工程目录路径不要包含任何中文
string.save("/hello.v","
struct Point {
pub mut: //声明下面的字段公开、可变
x int
y int
}
[export: 'add'] //一定要用这句指定DLL导出函数名
pub fn add(a int,b int,mut pt &Point) int {
pt.x = a+b
return a+b
}" )
/*
V语言是翻译成C语言然后生成DLL，生成的DLL依赖 VC 运行库，
试了换成调用TCC编译，10KB的DLL增大到 400KB，并且运行崩溃。
*/
process.v.shared("hello.v").waitOne();
//V生成的DLL建议至少在 WIN10 上用，需要VC++2017运行库
import sys.vc14;
sys.vc14.require(); //检测并自动安装 VC++ 运行库
//导入DLL，注意要指定 cdecl 调用约定
var dll = raw.loadDll("/hello.dll",,"cdecl")
//调用 V 函数( V是翻译为C语言，所以参考C语言的规则)
var n,pt = dll.add(12,3,{int x=1;int y =2});
//输出结果
console.log(n);
console.dumpJson(pt);
console.pause(true);相关推荐
- 无力吐槽的自动续费（你被自动续费困扰过吗?）
-
今天因为工作需要，需要在百度文库上下载一篇文章。没办法，确实需要也有必要，只能老老实实的按要求买了个VIP。过去在百度文库上有过类似经历，当时为了写论文买了一个月的VIP，后面也没有太注意，直到第二个...
- 百度文库推出“文源计划”创作者可一键认领文档
-
11月7日，百度文库发布了旨在保护创作者权益的“文源计划”。所谓“文源计划”，即为每一篇文档找到源头，让创作者享受更多的权益。据百度文库总经理李小婉介绍，文源计划分为三部分，分别是版权认证、版权扶持和...
- 有开放大学学号的同学，百度文库高校版可以用了。
-
还在网上找百度文库的下载方式，只要从身边的朋友在读开放大学的，那他（她）的学号就可以登陆到国家开放大学图书馆，还使用百度文库高校版来下载。与百度文库稍有不同，但足够使用了。现转国图链接如下：htt...
- 搜索资源方法推荐（搜索资源的方法）
-
今天msgbox就要教大家如何又快又准的搜到各类资源，第一点，排除干扰百度搜索出来啊经常前排展示它的产品以及百度文库，如何去除呢？很简单，后面输入空格减号百度文库，比如你搜高等数学百度文库很多，只要后...
- 一行代码搞定百度文库VIP功能（2021百度文库vip账号密码共享）
-
百度文库作为大家常用查资料找文档的平台，大多数文档我们都可以直接在百度文库找到，然而百度文库也有让人头痛的时候。好不容易找到一篇合适的文档，当你准备复制的时候他却提示你需要开通VIP才能复制~~~下载...
- 百度文库文档批量上传工具用户说明书
-
百度文库文档批量上传工具用户说明书1、软件主要功能1、批量上传文档到百度文库，支持上传到收费、VIP专享、优享以及共享。2、支持自动分类和自动获取标签3、支持多用户切换，一个账户传满可以切换到...
- 百度文库现在都看不到文档是否上传成功，要凉了吗?
-
打开知识店铺，百度文库文档里显示都是下载这一按键，上传的文档也看不到是否成功？咋情况，要取消了吗？没通过审核的也不让你删除，是几个意思，想通吃吗？现在百度上传文档也很费劲，有时弄了半天的资料上传审核过...
- 微信推广引流108式:利用百度文库长期分享软文引流
-
百度文库相对于百度知道、百度百科来说，操作上没那么多条条框框，规则上也相对好把握些。做一条百度知道所花费的精力一般都会比做一条百度文库的要多些，老马个人操作下来觉得百度文库更好把握。但见仁见智吧，今天...
- 职场“避雷”指南 百度文库推出标准化劳动合同范本
-
轰轰烈烈的毕业季结束了，众多应届生在经过了“职场海选”后，已正式成为职场生力军的一员。这一阶段，除了熟悉业务，签订劳动合同、了解职场福利也迅速被提上日程。而随着国人法律意识的增强，百度文库内《劳动合同...
- 《百度文库》:素材精选宝库（百度文库官网首页）
-
《百度文库》：独特功能助力选择高质量素材在当今信息爆炸的时代，如何高效地获取并利用有价值的素材成为了许多人面临的挑战。而《百度文库》作为百度公司推出的一款在线文档分享平台，凭借其丰富的资源、强大的功能...
- 深度整合和开放AI能力 百度文库和网盘推出内容操作系统「沧舟OS」
-
【TechWeb】4月25日消息，Create2025百度AI开发者大会上，百度文库和百度网盘推出全球首个内容操作系统——沧舟OS。基于沧舟OS,百度文库APP全新上线「GenFlow超能搭子」...
- 女子发现大二作业被百度文库要求付费下载，律师:平台侵权，应赔偿
-
近日，28岁的黎女士在百度百科搜索家乡的小地名时，发现了自己在大二完成的课题作业。她继续搜索，发现多个平台收录了该文，比如豆丁网和文档之家等，有的还设置了付费或积分下载。2月15日，九派新闻记者以用户...
- 2016杀入百度文库的新捷径，只有少数人才知道的喔
-
百度的产品在SEO优化中的分量真不用多说，其实很多人都像我一样一直在找捷径。但是我经常发现很多人都是在用死方法。比如发贴吧发帖而不知道去申请一个吧主，知道自问自答而不知道去申请一个合作资格。口碑和贴吧...
- 百度文库付费文档搜索方法（百度文库付费文档搜索方法有哪些）
-
一直以来，百度文库中无论是个人中心还是个人主页，都没有像淘宝一样的店内搜索功能，连最近新开的知识店铺也没有设计店内搜索功能，这无论是对上传用户还是下载用户都不方便，上传用户想要搜索自己的文档无法办到...
- 供读者免费使用!泰达图书馆机构版百度文库新年上新啦
-
在泰达图书馆读者使用百度文库数字资源不需要VIP，免-费-用！惊不惊喜？快来了解一下吧……新年伊始，为满足区域企业、高校、科研院所以及居民群众在教学、科研及学习过程中，对各类文献资源的需求，泰达图书馆...
欢迎 你 发表评论:
- 一周热门
- 最近发表
- 标签列表
-
- 如何绘制折线图 (52)
- javaabstract (48)
- 新浪微博头像 (53)
- grub4dos (66)
- s扫描器 (51)
- httpfile dll (48)
- ps实例教程 (55)
- taskmgr (51)
- s spline (61)
- vnc远程控制 (47)
- 数据丢失 (47)
- wbem (57)
- flac文件 (72)
- 网页制作基础教程 (53)
- 镜像文件刻录 (61)
- ug5 0软件免费下载 (78)
- debian下载 (53)
- ubuntu10 04 (60)
- web qq登录 (59)
- 笔记本变成无线路由 (52)
- flash player 11 4 (50)
- 右键菜单清理 (78)
- cuteftp 注册码 (57)
- ospf协议 (53)
- ms17 010 下载 (60)